PRTBYT takes a byte and sends it to the serial TY as two hex ascii characters
The byte is entered in A, two characters are printed and A is saved.

0914   1E3B             ;		
0915   1E3B             ;       PRINT 1 HEX BYTE AS 2 ASCII CHAR'S
0916   1E3B             ;   
0917   1E3B 85 FC       PRTBYT  STA   TEMP                             
0918   1E3D 4A                  LSR   A           ; SHIFT CHAR RIGHT 4 BITS
0919   1E3E 4A                  LSR   A
0920   1E3F 4A                  LSR   A
0921   1E40 4A                  LSR   A
0922   1E41 20 4C 1E            JSR   HEXTA       ; CONVERT TO HEX AND PRINT
0923   1E44 A5 FC               LDA   TEMP        ; GET OTHER HALF
0924   1E46 20 4C 1E            JSR   HEXTA       ; CONVERT TO HEX AND PRINT
0925   1E49 A5 FC               LDA   TEMP        ; RESTORE BYTE IN A AND RETURN
0926   1E4B 60                  RTS   
0927   1E4C             ;
0928   1E4C 29 0F       HEXTA   AND   #$0F        ; MASK HI 4 BITS
0929   1E4E C9 0A               CMP   #$0A
0930   1E50 18                  CLC   
0931   1E51 30 02               BMI   HEXTA1
0932   1E53 69 07               ADC   #$07        ; ALPHA HEX
0933   1E55 69 30       HEXTA1  ADC   #$30        ; DEC HEX
0934   1E57 4C A0 1E            JMP   OUTCH       ; PRINT CHAR

What is happening here?

• The byte in A is saved (917)
• the high nibble is shifted to the lower nibble (918-921)
• the nibble is converted to hex (922, calls hexta)
• the byte is restored and the low nibble converted to hex
• A is restored
• hexta masks off low nibble (928)
• convert A..F to ascii (929-932)
• convert hex to ascii and print(933-934)

GETBYT and PACK

1148   1F9D             ;		
1149   1F9D             ;       GET 2 HEX CHAR'S AND PACK 
1150   1F9D             ;       INTO INL AND INH
1151   1F9D             ;       X PRESERVED Y RETURNED = 0
1152   1F9D             ;       NON-HEX WILL BE LOADED AS NEAREST HEX EQU
1153   1F9D             ;
1154   1F9D 20 5A 1E    GETBYT  JSR   GETCH
1155   1FA0 20 AC 1F            JSR   PACK
1156   1FA3 20 5A 1E            JSR   GETCH
1157   1FA6 20 AC 1F            JSR   PACK
1158   1FA9 A5 F8               LDA   INL
1159   1FAB 60                  RTS
1160   1FAC             ;		
1161   1FAC             ;       SHIFT CHAR IN A INTO
1162   1FAC             ;       INL AND INH 
1163   1FAC             ;
1164   1FAC C9 30       PACK    CMP   #$30       ; CHECK FOR HEX 
1165   1FAE 30 1B               BMI   UPDAT2
1166   1FB0 C9 47               CMP   #$47       ; NOT HEX EXIT
1167   1FB2 10 17               BPL   UPDAT2
1168   1FB4 C9 40               CMP   #$40       ; CONVERT TO HEX
1169   1FB6 30 03               BMI   UPDATE
1170   1FB8 18                  CLC   
1171   1FB9 69 09               ADC   #$09
1172   1FBB 2A          UPDATE  ROL   A
1173   1FBC 2A                  ROL   A
1174   1FBD 2A                  ROL   A
1175   1FBE 2A                  ROL   A
1176   1FBF A0 04               LDY   #$04       ; SHIFT INTO I/O BUFFER
1177   1FC1 2A          UPDAT1  ROL   A
1178   1FC2 26 F8               ROL   INL
1179   1FC4 26 F9               ROL   INH
1180   1FC6 88                  DEY   
1181   1FC7 D0 F8               BNE   UPDAT1
1182   1FC9 A9 00               LDA   #$00       ; A=0 IF HEX NUM
1183   1FCB 60          UPDAT2  RTS

What is happening here?

GETBYT
The GETBYT routine is used in the TTY part of the KIM-1 monitor to enter two hex characters (0..9 and A..F) and pack it into one byte.

• read the first character (1154)
• pack it into INL lower nibble (1155)
• read the second character (1156)
• pack it into INL, shifting the lower nibble to high and shifting in the second nibble (1157)
• return byte from INL to A

PACK

• check if < '0' and error out with A > 0 (1164-1165)
• check if > ‘F’ and error out with A > 0 (1166-1167)
• if A..F add $09 (1168-1171)
• shift in nibble via INH and INL
• return zero if valid hex but with invalid Z flag

Note that the range between ‘9’ and ‘A’ is not checked, so those are taken as valid hex characters.
The PACK routine accepts ‘:’– ‘?’, $3A .. $3F as valid hex characters A ..F.

KIM
0200 A9 ;;
00BB 00 ::
00AA 00 ????
FFFF 1C

The ASCII encoding is arranged so that adding 9 to ‘A’–’F’ aligns them perfectly with the desired hexadecimal nibble after four left rotates. This avoids a separate subtraction of ‘A’ and addition of 10.

The following demo with PRTBYT and GETBYT illustrates how this could be done in a user program.

0001   0000             ;
0002   0000             ; GETBYTC with error checking
0003   0000             ; illustrates shortcomings in PACK
0004   0000             ; - G and ; and possibly more accepted without error
0005   0000             ;
0006   0000             ;
0007   0000             ; KIM
0008   0000             ; 0000 00 200
0009   0000             ; 0200 A9 G
0010   0000             ; >12=12
0011   0000             ; >33=33
0012   0000             ; >H?
0013   0000             ; >G?
0014   0000             ; >::=AA
0015   0000             ; >;;=BB
0016   0000             ; >AB=AB
0017   0000             ; >CD=CD
0018   0000             ; >EE=EE
0019   0000             ; >
0020   0000             
0021   0000             ; KIM-1 defines
0022   0000             ;
0023   0000             PACK 	= 	$1FAC		; pack hex character into INL, shift in
0024   0000             PRTBYT	= 	$1E3B		; print byte as 2 hex characters
0025   0000             GETCH	=	$1E5A		; receive character from TTY serial
0026   0000             OUTCH	= 	$1EA0		; send character via TTY serial
0027   0000             INL		= 	$F8	
0028   0000             INH		= 	$F9
0029   0000             ;
0030   0200             	.org $0200
0031   0200             
0032   0200             ; demo code
0033   0200             ;
0034   0200 A9 00       LOOP 	LDA	#$00
0035   0202 85 F8       		STA INL			; zero hex byte
0036   0204 85 F9       		STA	INH
0037   0206 20 42 02    		JSR CRLF
0038   0209 A9 3E       		LDA #'>'		; prompt
0039   020B 20 A0 1E    		JSR OUTCH
0040   020E 20 28 02    		JSR GETBYTC
0041   0211 90 08       		BCC	OK 
0042   0213 A9 3F       		LDA #'?'		; error
0043   0215 20 A0 1E    		JSR OUTCH
0044   0218 4C 00 02    		JMP LOOP
0045   021B             ;		
0046   021B 48          OK		PHA
0047   021C A9 3D       		LDA	#'='
0048   021E 20 A0 1E    		JSR OUTCH
0049   0221 68          		PLA
0050   0222 20 3B 1E    		JSR PRTBYT
0051   0225 4C 00 02    		JMP LOOP		; repeat	
0052   0228             ;
0053   0228             ; subroutine GETBYTC
0054   0228             ; read 2 hex characters from TTY input
0055   0228             ; pack into one byte
0056   0228             ; Returns: carry clear if hex OK, A == hex byte
0057   0228             ; clobbers X and Y
0058   0228             ;
0059   0228             
0060   0228             
0061   0228 20 5A 1E    GETBYTC	JSR	GETCH		; read character
0062   022B 20 AC 1F    		JSR	PACK		; pack into INL
0063   022E C9 00       		CMP #$00		; restore z flag
0064   0230 D0 0E       		BNE EGETB		; A = 0 if hex number
0065   0232 20 5A 1E    		JSR	GETCH		; read second character
0066   0235 20 AC 1F    		JSR	PACK		; pack into INL
0067   0238 C9 00       		CMP #$00		; restore z flag
0068   023A D0 04       		BNE EGETB		; A = 0 if hex number
0069   023C A5 F8       		LDA	INL
0070   023E 18          		CLC
0071   023F 60          		RTS
0072   0240 38          EGETB	SEC
0073   0241 60          		RTS
0074   0242             		
0075   0242 A9 0D       CRLF	LDA 	#$0D
0076   0244 20 A0 1E    		JSR 	OUTCH
0077   0247 A9 0A       		LDA 	#$0A
0078   0249 20 A0 1E    		JSR		OUTCH 
0079   024C 60          		RTS
0080   024D             
0081   024D             		.END
0082   024D             		
0083   024D             
tasm: Number of errors = 0

See also:

Jolt with 4K and power supply

With thanks to Jonathan Chapman of Glitchworks who found a Jolt system, here images of a Jolt with 4K memory, an experim...

TERC KIM-1 Interface set

A recent acquisition, the TERC (Technical Education Research Centers) KIM-1 Interface set. An educational tool to work w...

6502 tester NMOS CMOS 1-8MHz

The 6502 W65C02 6502C CPU tester NMOS / CMOS 1-8MHz is a CPU tester for 40 pin 6502/65C02 and WD65C02 and Sally. The...

680x/650x Test system

The 680x/650x Test system allows to test, with the CPU itself performing the test, the MC680X and MCS650X families. T...

Some tips that I learned programming for the KIM-1 and the 6502.

ALWAYS CHECK YOU DO NOT FORGET IMMEDIATE ACCESS SYNTAX!
It so easy an common to forget the ‘#’ in your assembler code. Assemblers will not complain and make it absolute or zeropage addressing and you will search for hours!

TTY routines

Do not use the CRLF routine at $1E2F in the monitor

This routine sends the CR and LF to the TTY output vai OUTCH. Nice, you will need that often in a console program.
But if you read the page on printing a string you see this routine also sends out 6 Null ($00) characters, this takes a lot of wasted time!

Just make your own subroutine

LDA #$0D   ; CR
JSR OUTCH
LDA #$0A   ; LF
JSR OUTCH
RTS

Note that this destroys A and Y!

GETCH gets a character to serial TTY.
Blocking, it waits indefinitely for a character to arrive and A will have the value.
The routine also kills the Y register, returns with Y = $FF.
Also, in LED Display and Keyboard mode, it returns with A = $01 and X = 8.
Save Y before calling GETCH, and restore Y when it returns.

OUTCH sends a character to serial TTY
No handshaking, no hardware flow control, it just spits out the character.
A destroyed, Y=FF, X preserved.
Save at least Y, and saving A is recommended.

SPACE print a blank

This just calls OUTCH with A = $20, so read OUTCH for the side effects.

PRTBYT Print A as two hex characters

Uses OUTCH, so Y is lost. A is preserved.

GETBYT and GETBYTC

X saved, Y = 0, A is hex character
Reads two hex characters (0..9 A..F) and tries to pack them in A.
See the page on PRTBYT,GETBYT and PACK for an error checking alternative GETBYTC to GETBYT.
Note that due to an incomplete check ‘:’– ‘?’, $3A .. $3F are accepted as valid hex characters A ..F.

KIM
0200 A9 ;;
00BB 00 ::
00AA 00 ????
FFFF 1C

The audio tape routines

The DUMPT and LOADT routines are OK to call interactively to dump and load KIM-1 files on tape.
The cannot be called as subroutines. when finished they return to the KIM-1 monitor.
DUMPT return with $0000 as current address pointer in the KIM-1 monitor.
LOADT returns it status via the current address pointer in the KIM-1 monitor, $0000 is success, $FFFF is a loading error.

What you can do is:
– Have code at $0000 to return to your program (Warm start entry), so the user just has to press G
– instruct the user what to do if DUMPT returns $FFFF

The better solution is to incorporate Hypertape as callable subroutine.

Return to the KIM-1 monitor

The preferred location to call to enter the KIM-1 monitor form a user program is START at $1C4F

Reading the keyboard and lighting the display

Fill F9, FA, FB with the values to show on the LED displays
Call SCAND
Call SCAND to debounce
CaLl GETKEY
Now check the key in A:
– above $14 : no key
– 14 = PC
– 13 = GO
– 12 = +
– 11 = DA
– 10 = AD
– 0 ..9 A – F keys
Handle key and loop back to the begin

KIM-1 TTY command summary

– Connect the application connector with a TTY switch
– Serial port in your terminal emulator settings 9600 bps (or less, 4800 or 2400 work best), 8N1
– Add character and line delay in your terminal emulator, see the TTY problems page
– Press Enter (or any key with odd ASCII value after Reset to initialize serial bit rate.

After startup give the NMI and IRQ/BRK vector a known value

NMI Initialization for Single Step and Stop
17FA 00
17FB 1C

IRQ Initialization for BRK
17FE 00
17FF 1C

Make sure you are not in decimal mode:
00F1 00

Machine Context saved/restored by ST/GO
00EF PC low
00F0 PC high
00F1 Status Register (flags)
00F2 Stack Pointer
00F3 A
00F4 Y
00F5 X

Breakpoints
– Write BRK instruction ($00) at desired address, program will be stopped here.
– ST button: Pressing will invoke NMI interrupt.
– Single Step: Set SST switch to on, type G to step one instruction from current location.

Cassette Load and Save

12 Volt power source is only required when reading tapes

Save to tape
– Store $00 in $00F1 (to ensure CPU is in binary mode).
– Save start address (low/high) in $17F5, $17F6.
– Save end address+1 (low/high) in $17F7, $17F8.
– Write tape ID ($01-$FE) in $17F9.
– Start tape in record mode.
– Run address $1800 (DUMPT) to save.

Load from tape
– Store $00 in $00F1 (to ensure CPU is in binary mode).
– Write tape ID ($01-$FE, $00 loads any ID, $FF loads using start address values (low/high) in $17F5, $17F6) to $17F9.
– Run address $1873 (LOADT) to load.
– success of load: current address is 0000, error is FFFF

TTY commands

<hex address>         Show data at current address 
                      (hex characters shifted in to the left) 
<hex data&>.          Write to current address 
<Return>              Next address 
<Line Feed>           Move to previous address  (CTRL/J)
L                     Load program from paper (error if ERR KIM is displayed)
Q                     Save memory to paper tape, saves from current address 
                      to end address stored at $17F7 (low), $17F8 (high) 
G                     Start program at current address 
                      (note: set F1 00 if not in SST mode) 
RUB OUT               restart the KIM-1 monitor

Note that pressing RUB OUT in current terminal emulators is not a standard key. I have done it with some customization in Teraterm for Windows.
In the KIM-1 Simulator the RUBOUT is patched to CTRL-G.